{
  description = "An over-engineered collection of config files managed via Nix";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixgl = {
      url = "github:guibou/nixGL";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    neovim-plugins = {
      url = "github:NixNeovim/NixNeovimPlugins";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    firefox-addons = {
      url = "gitlab:rycee/nur-expressions?dir=pkgs/firefox-addons";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    xremap = {
      url = "github:xremap/nix-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    # Pinning conan 1.53.0, not available in 'unstable' anymore.
    conan.url = "nixpkgs/55070e598e0e03d1d116c49b9eff322ef07c6ac6";
  };

  outputs = inputs@{ nixpkgs, home-manager, nixgl, firefox-addons, neovim-plugins, xremap, ... }:
  let
    system = "x86_64-linux";
    pkgs = import nixpkgs {
      inherit system;
      config.allowUnfree = true;
      overlays = [
        nixgl.overlay
        neovim-plugins.overlays.default
        (_: _: { firefoxAddons = firefox-addons.packages.${system}; })
        (_: _: { conan = (import inputs.conan { inherit system; }).conan; })
      ];
    };
  in {

    # Mincepie
    homeConfigurations.mincepie = home-manager.lib.homeManagerConfiguration {
      inherit pkgs;
      extraSpecialArgs = { inherit xremap; };
      modules = [
        ./users/dyamon/mincepie.nix
      ];
    };
    nixosConfigurations.mincepie = nixpkgs.lib.nixosSystem {
      inherit system;
      modules = [
        ./system/mincepie/configuration.nix
      ];
    };

    # Chimera
    homeConfigurations.chimera = home-manager.lib.homeManagerConfiguration {
      inherit pkgs;
      extraSpecialArgs = { inherit xremap; };
      modules = [
        ./users/dyamon/chimera.nix
      ];
    };

  };
}